#!/usr/bin/awk

function handle_table(str)
{
	entries = 0;

	sub(/<table[^>]*>/, "<variablelist>");
	print;
	while (getline) {
		# end of table
		if (sub(/<\/table>/, "</variablelist>")) { return; }
		
		if (sub(/<row>/, "<varlistentry>")) { entries = 0; }
		if (sub(/<\/row>/, "</varlistentry>")) {
			if (entries > 1)
				print "</listitem>";
		}
		if ($0 ~ /<entry>/) {
			entries++;
			if (entries == 1 )
				sub(/<entry>/, "<term>");
			else {
				print "<listitem>";
				sub(/<entry>/, "<para>");
			}
		}	
		if ($0 ~ /<\/entry>/) {
			if (entries == 1 )
				sub(/<\/entry>/, "</term>");
			else {
				sub(/<\/entry>/, "</para>");
			}
		}	

		print;
	}
}

# multiline MAN: comment
/<!-- MAN:$/ {
	while (getline) {
		if ($0 ~ /^-->$/) break;
		print;
	}
	next;
}
# MAN: on one line
/<!-- MAN:/ {
	n = split($0, a, "-->");
	for (i = 1; i <= n; i++) {
		#printf "a[%d] = '%s'\n", i, a[i];
		if (a[i] ~ /<!-- MAN:/) {
			sub(/<!-- MAN:/, "", a[i]);
			sub(/[ \t]+$/, "", a[i]);
			printf "%s", a[i];
		}
		else if (a[i] ~ /<!-- /)
				printf "%s -->", a[i];
			else printf "%s", a[i];
	}
	next;
}

# remove "<sect1 .*</title>"
/<sect1/ {
	while (getline) {
		if (sub(/^.*<\/title>/, "")) { print; break; }
	}
	next;
}

/<table / {
	handle_table($0);
}

# default: print line
// {
	sub(/<\/sect1>/, "");
	print;
}

# vim: ft=awk cindent