File: [Platon] / doc / diplomova-praca-rajo / images / slide-analytic.gpi (download)
Revision 1.2, Sun Jan 16 15:01:30 2005 UTC (19 years, 2 months ago) by rajo
Changes since 1.1: +2 -2
lines
Fix: gnuplot 4.0 has different syntax (incompatible with gnuplot 3.7.x)
Change lines from:
set linestyle 1 linetype 7 linewidth 1
to:
set line style 1 linetype 7 linewidth 1
|
#!/usr/bin/gnuplot
reset
#set terminal postscript enhanced
#set output "slide-analytic.ps"
set terminal postscript eps enhanced 24
set output "slide-analytic.eps"
set line style 1 linetype 7 linewidth 1
set line style 2 linetype 1 linewidth 3
set multiplot
set size 1.0,1.0
set lmargin 9
set rmargin 2
set key samplen 0.7
set mytics 2
set mxtics 2
set format y " %2.2f"
lambda = 0.001
acc = 1e7
u_drift(x,y) = x / y / sqrt(lambda * acc)
# ------------------------------------------------------------------------
# +-----+ +-----+
# | X | | |
# +-----+ +-----+
# +-----+ +-----+
# | | | |
# +-----+ +-----+
set origin 0.0,0.5
set size 0.5,0.5
set key bottom
set ytics 0.2
set xlabel "{/Symbol t}\n a)"
set ylabel "u_d({/Symbol t})"
set label "{/Symbol \341z\361 / t}" at 3,0.6
plot [:8][0:0.9] "analytic.dat" notitle with lines 1, \
sqrt(2/pi) notitle with lines 2, \
"N-1e6_a-1E7_T-0.dat" using 2:(u_drift($5, $1)) notitle with lines 1
set nolabel # remove <\dzeta> / \ tau from graphs
set format y "%2.3f"
# ------------------------------------------------------------------------
# +-----+ +-----+
# | | | |
# +-----+ +-----+
# +-----+ +-----+
# | X | | |
# +-----+ +-----+
set origin 0.0,0.0
set size 0.5,0.5
set key bottom
set ytics 0.002
set xlabel "{/Symbol t}\n c)"
set ylabel "u_d({/Symbol t})"
plot [:8][0.795:0.801] "analytic.dat" notitle with lines 1, \
sqrt(2/pi) notitle with lines 2, \
"N-1e6_a-1E6_T-0.dat" using 2:6 notitle w l 1
set format y "%2.2f"
# ------------------------------------------------------------------------
# +-----+ +-----+
# | | | X |
# +-----+ +-----+
# +-----+ +-----+
# | | | |
# +-----+ +-----+
set origin 0.5,0.5
set size 0.5,0.5
set lmargin 9
set rmargin 2
set key top
set ytics 0.01
#set ytics ("0.795" 0.795, "0.800" 0.800, "0.805" 0.805, "0.810" 0.810, "0.815" 0.815, "0.820" 0.820)
set xlabel "{/Symbol t}\n b)"
set ylabel "u_d({/Symbol t})"
plot [:8][0.793:0.82] "analytic.dat" notitle with lines 1, \
sqrt(2/pi) notitle with lines 2, \
"N-1e6_a-1E7_T-0.dat" using 2:6 notitle with lines 1
# ------------------------------------------------------------------------
# +-----+ +-----+
# | | | |
# +-----+ +-----+
# +-----+ +-----+
# | | | X |
# +-----+ +-----+
# Entropia:
set origin 0.5,0.0
set size 0.5,0.5
set lmargin 9
set rmargin 2
set key bottom
set xtics autofreq
set ytics autofreq
# zavislost chyby od poctu simulovanych ionov {{{
#set grid
#set xtics ( "10^3" 1e3, "10^4" 1e4, "10^5" 1e5, "10^6" 1e6, "10^7" 1e7, "10^8" 1e8)
#set ytics ("10^{-4}" 1e-4, "10^{-3}" 1e-3, "10^{-2}" 1e-2, "10^{-1}" 1e-1)
#set xlabel "N\n d)"
#set ylabel "\n\n{/Symbol e}"
#
#set logscale xy
#
#plot [1e3:1e8][] "analytic-chyba.dat" title "MC" with points, \
# 0.7 / sqrt(x) notitle
#
# }}}
set ytics 0.2
set xlabel "{/Symbol t}\n d)"
set ylabel "S({/Symbol t})"
set label 1 "-{/Symbol S}_i {/Symbol f}_i({/Symbol t}) ln{/Symbol f}_i({/Symbol t})" at 2,0.4
plot [:8][:0.8] \
"distrib-N-1e6_lambda-3e-7_a-1e10_T-0.ENTROPY.dat" using 2:3 \
notitle with l, \
log(sqrt(pi/2)) + 0.5 notitle
set nomultiplot
# vim600: fdm=marker fdl=0 fdc=3
Platon Group <platon@platon.org> http://platon.org/
|